Monohedral convex pentagonal tile, type 15 (OpenSCAD)

The full name is "Monohedral convex pentagonal tile, type 15". It is a tessellating shape that was discovered in 2015 by Mann/McLoud/Von Derau.

This simple script can create 48 of those shapes with the default settings. They can be given as a gift to someone, as a mathematical puzzle.

Basic information can be found at Wikipedia: https://en.wikipedia.org/wiki/Pentagonal_tiling#Monohedral_convex_pentagonal_tilings

For the script I used the information from this page by Mike Garrity: https://blogs.mathworks.com/graphics/2015/08/19/type-15-convex-pentagon/

If you are interested in math, then mathgrrl (Laura Taalman) made a OpenSCAD script for all the pentagons: https://www.printables.com/model/33911-every-convex-tessellating-pentagon-for-boxes-brace
She has other mathematical models, see mathgrrl on Thingiverse: https://www.thingiverse.com/mathgrrl

The same tile was uploaded by Justyna Wojtczak: https://www.printables.com/model/354182-pentagonal-tile-that-was-unsolved-for-30-years

Making the tessellation

The pattern repeats after twelve rows. 
The rows and columns will become clear when the script is loaded in OpenSCAD and the number of rows and columns are changed.

The corners of the pentagonal tile have angles of 135, 60, 150, 90 and 105 degrees. In the tessellation there are always two bottoms against each other.
In the tessellation, half of the tiles are upside-down. The tiles are rotated at angles of 30, 60, 150, 210, 240 and 330 degrees. There are six tiles at those angles and another six tiles upside-down at those angles.

I think there is a way to make the tessellation from memory.
Start with a tile. I use the same orientation as Wikipedia.

Use six tiles to make these patterns. The bottoms are always against each other.
If you look closer, then it is not hard to remember. The two on the right are the same and are mirrored, the one on the left has the same right-half as the others and the left-half is not mirrored but turned around.

Organize them in this way.

That makes the six lower rows. Add more to the right of it to get more columns.

Make another set of the lower six rows and flip it upside down horizontally. Those are the six upper rows.

Connect all the rows together.

(I have accidently used 5 columns for the bottom rows and 4 columns for the top rows)

OpenSCAD

OpenSCAD uses a script for 3D solid modelling. OpenSCAD is free software and can be downloaded from the website https://openscad.org/

When the script “Typ15.scad” is opened in OpenSCAD, then the "Customizer" window can set the size of the tiles and the number of rows and columns. At half the size, there is still enough space between the tiles for the slicer to make separate tiles.

Script

The script below is the same as the attached file “Type15.scad”.

// Type15.scad
//
// "Monohedral convex pentagonal tile, type 15"
//
// December 31, 2022
// Script by Stone Age Sculptor
// License CC0
//
// This script creates 48 of those tiles,
// but the size of the shape and repetitions are customizable.
// The tiles can be used on both sides.
// The columns are easily extendible to the right.
// The pattern repeats after 12 rows.
// They can be given as a gift, as a mathematical puzzle.
//
// This shape was discovered in 2015.
// Explanation:
//   https://en.wikipedia.org/wiki/Pentagonal_tiling
// Coordinates and visual tessellation layout from Mike Garrity:
//   https://blogs.mathworks.com/graphics/2015/08/19/type-15-convex-pentagon/
//

columns = 4;   // [1:20]
rows = 12;     // [1:60]
scaling = 30;  // [1:100]
thickness = 3; // [1:10]  thickness in mm

/*[Hidden]*/   // Hide the rest of the variables

// Coordinates for the shape
// https://blogs.mathworks.com/graphics/2015/08/19/type-15-convex-pentagon/
shape = [
  [0,0],
  [-1/4,sqrt(3)/4],
  [-(3+sqrt(3))/4,(1+sqrt(3))/4],
  [-(4+sqrt(3))/4,1/4],
  [-1,0],
];

// There are 12 possible rows.
// The positions are defined here.
// It starts with the first row at the bottom.
// The data is:
//   x_offset, y_offset, rotation, upside down

position = [
 [ 2.12, 0.50,  30, 0],
 [ 0.31, 0.78, 210, 0],
 [ 0.29, 0.81, 150, 1],
 [ 1.19, 1.32, 240, 0],
 [ 0.48, 2.89, 240, 1],
 [ 1.00, 3.41, 150, 0],
 [ 1.02, 3.43, 210, 1],
 [ 1.42, 3.70,  30, 1],
 [ 1.46, 3.71, 330, 0],
 [ 1.97, 4.23,  60, 1],
 [ 1.24, 5.78,  60, 0],
 [ 2.15, 6.31, 330, 1],
];

tile_length = 1.43;                // length of single tile
height_twelve = scaling*5.83;      // height of all 12 tiles

linear_extrude(thickness)          // turn flat 2D to a 3D shape
{
  // The lowest row starts at the bottom.
  for(r=[0:rows-1])
  {
    for(c=[0:columns-1])
    {
      r_repeat = r%12;            // after 12 rows, it repeats
      r_fullset = floor(r/12);    // after 12 rows, it repeats
      x = scaling*(c*tile_length+position[r_repeat][0]);
      y = scaling*(position[r_repeat][1])+r_fullset*height_twelve;
      translate([x,y])
        mirror([0,position[r_repeat][3]])
          Type15(position[r_repeat][2]);
    }
  }
}

module Type15(rot)
{
  // rotate the shape
  rotate(rot)
    // enlarge to a usuable size
    scale(scaling)
      // create the shape with the coordinates
      polygon(shape);
}

Credits

The shape was discovered in 2015 by Casey Mann, Jennifer McLoud-Mann, and David Von Derau.
The script and the (rendered) pictures and the way to make the tessellation from memory are by me and I make them public domain.